zurück zur Übersicht

Fehlerzellen farbig hervorheben

 

Bei der Überprüfung einer Tabelle auf mögliche Fehler ist es wichtig, diese schnell und sicher zu erkennen. Dabei ist es sehr hilfreich, entdeckte Fehler auffällig zu markieren.

Eine sehr effiziente Art der Markierung können Sie mit einer bedingten Formatierung in Ihre Tabellen integrieren. Ähnlich einer Ampel können Sie beispielsweise als korrekt erkannte Zellen Grün und identifizierte Fehlerzellen Rot hinterlegen.

In einer Tabelle wird eine Addition durch eine Probe, die in einer anderen Zelle durchgeführt wird, überprüft. Wenn beide Summen nicht identisch sind, liegt ein Fehler vor.

Die folgende Abbildung zeigt die Beispieltabelle, in der in der Zelle F16 die Summe der Zelle F14 überprüft wird:

Für die Einrichtung der Warnmarkierung bei fehlerhafter Probe markieren Sie die Probezelle. Rufen Sie anschließend im Menü „Format“ den Befehl „Bedingte Formatierung“ auf. Unter „Bedingung 1“ aktivieren Sie die Option „Formel ist“ und tragen die folgende Formel ein:

=$F$16=$F$14

„Format“ im Register „Muster“ die Hintergrundfarbe Grün. Das bestätigen Sie mit „OK“ und kehren so in die Dialogbox der bedingten Formatierung zurück.

Über die Schaltfläche „Hinzufügen“ richten Sie die zweite Bedingung mit der folgenden Formel ein:

=$F$16<>$F$14

Für die zweite Bedingung, die greift, wenn ein Fehler vorliegt, legen Sie die Hintergrundfarbe Rot fest.

Die folgende Abbildung zeigt die Dialogbox der bedingten Formatierung mit den beiden Formeln:

Nach der Bestätigung mit „OK“ ist Ihre kleine Ampel eingerichtet. Wenn die Probe das Berechnungsergebnis bestätigt, erscheint die Zelle Grün und alles ist in Ordnung. Bei roter Probezelle sollten Sie sich auf die Fehlersuche machen. Die folgende Abbildung zeigt die bedingte Formatierung in der Tabelle:

Die Beispieltabelle mit der vorgestellten Darstellung finden Sie hier in der Arbeitsmappe TuM_8_11.xls in der Tabelle „Fehler“.

zurück zum Seitenanfang

Bedingte Addition mit mehreren Kriterien

In einer Tabelle werden Produktionszahlen nach Quartalen erfasst. Die folgende Abbildung zeigt einen Auszug aus der Beispieltabelle:

Aus dieser Tabelle sollen nun für verschiedene Auswertungen Summen für mehrere Produkte gebildet werden. Auf den ersten Blick ist das ein klarer Fall für die Funktion SUMMEWENN. Diese hilft jedoch nicht weiter, da sie lediglich ein Suchkriterium verarbeiten kann.

In diesem Fall hilft die häufig vergessene Funktion DBSUMME. Diese setzen Sie folgendermaßen ein:

Legen Sie an einer nicht benötigten Position in Ihrer Tabelle einen Kriterienbereich an. In diesem geben Sie in die erste Zeile den Titel der Spalte Ihrer Liste ein, die die Produktbezeichnungen enthält – in der Beispieltabelle „Produkte“ (ohne Anführungszeichen).

Darunter tragen Sie dann die Namen der Produkte ein, deren Zahlen Sie addieren möchten. Die folgende Abbildung zeigt den Kriterienbereich im Zellbereich G1:G6:

Für die Addition der Werte der Produkte im Kriterienbereich verwenden Sie die folgende Formel:

=DBSUMME(A1:E16;"1. Quartal";G1:G6)

Die Abbildung auf der folgenden Seite zeigt den Einsatz der Formel für die bedingte Addition mit mehreren Kriterien in der Beispieltabelle:

Die Beispieltabelle mit der Addition nach Kriterien finden Sie hier in der Arbeitsmappe TuM_8_11.xls. Verwenden Sie das Tabellenblatt „DBSUMME“.

zurück zum Seitenanfang

Einträge mit Zusätzen hervorheben

In einer Liste in einer Excel-Tabelle werden Firmennamen erfasst. Bei einigen steht lediglich der Name, andere tragen einen Firmenzusatz.

Die folgende Abbildung zeigt einen Ausschnitt aus der Beispieltabelle:

In dieser Liste sollen die Einträge in der Spalte B mit dem Text „GmbH“ markiert werden, die den Zusatz GmbH in der Spalte A tragen.

Zur Lösung dieser Aufgabe tragen Sie die folgende Formel in die Zelle B2 ein:

=WENN(ISTFEHLER(FINDEN("GmbH";A2));"";"GmbH")

Diese Formel kopieren Sie dann in der Spalte B ausreichend weit nach unten. Die folgende Abbildung zeigt den Einsatz der Formel zur Markierung der GmbH in der Beispieltabelle:

Wenn Sie nicht nur die GmbHs, sondern auch andere Gesellschaftsformen berücksichtigen möchten, müssen Sie die Abfrage um eine UND-Funktion erweitern, in der Sie die einzelnen Texte angeben.

Die folgende Formel beispielweise gibt den Text „Gesellschaft“ zurück, wenn die Zusätze „GmbH“, „AG“ oder „GbR“ enthalten sind:

=WENN(UND(ISTFEHLER(FINDEN("GmbH";A2));ISTFEHLER(FINDEN("AG";A2));ISTFEHLER(FINDEN("GbR";A2)));"";"Gesellschaft")

Die folgende Abbildung zeigt den Einsatz dieser Formel in der Beispieltabelle:

Statt einen Text in einer neuen Spalte einzutragen, können Sie auch die Zellen in der Adressspalte markieren, die einen Firmenzusatz enthalten.

Dazu nutzen Sie die bedingte Formatierung. Für die Einrichtung gehen Sie folgendermaßen vor:

Markieren Sie den Zellbereich, der die Namen enthält – in der Beispieltabelle A3:A15. Dann rufen Sie im Menü „Format“ den Befehl „Bedingte Formatierung“ auf.

In der erscheinenden Dialogbox wählen Sie im Listfeld „Bedingung 1“ die Option „Formel ist“. In das Eingabefeld tragen Sie die folgende Formel ein:

=WENN(UND(ISTFEHLER(FINDEN("GmbH";A2));ISTFEHLER(FINDEN("AG";A2));ISTFEHLER(FINDEN("GbR";A2)));"";1)

Diese Formel sucht nach den Gesellschaftsformen GmbH, AG und GBR. Bei Bedarf können Sie noch weitere ergänzen.

Nach der Eingabe der Formel klicken Sie auf „Format“ und wählen in der erscheinenden Dialogbox im Register „Muster“ eine Farbe aus, mit der die Zellen, die einen Firmenzusatz enthalten, hinterlegt werden sollen. Das bestätigen Sie mit „OK“ und kehren zur bedingten Formatierung zurück.

Die folgende Abbildung zeigt die Dialogbox der bedingten Formatierung mit den beschriebenen Einstellungen:

Diese Einstellungen bestätigen Sie mit „OK“. In der Tabelle sind dann die gewünschten Einträge markiert.

Die folgende Abbildung zeigt die bedingte Formatierung in der Beispieltabelle:

Die Beispieltabelle mit der vorgestellten Darstellung finden Sie hier in der Arbeitsmappe TuM_8_11.xls in der Tabelle „Markierung“.

zurück zum Seitenanfang

Werte auf Teilbeträge mit Rest verteilen

In einer Tabelle sollen ganze Zahlen in verschiedene Teilbeträge zerlegt werden. Dabei soll eine ganze Zahl ohne Komma als Ergebnis geliefert werden. Ein eventueller Rest ist also zu ignorieren. In einem zweiten Schritt soll der Rest zu einem der Teilbeträge hinzugezählt werden. Konkret: Die Zahl 455 ist in acht Teile zu zerlegen. Das Ergebnis ist siebenmal 56 und einmal 63.

Legen Sie sich dazu eine kleine Tabelle an. Der aufzuteilende Wert steht in B1 und in B2 steht die Anzahl der gewünschten Teile. Die folgende Abbildung zeigt das in der Beispieltabelle:

Die ganze Zahl ohne Rest ermitteln Sie mit der folgenden Formel:

=GANZZAHL(B1/B2)

Die folgende Abbildung zeigt den Einsatz der Formel in der Beispieltabelle:

Den verbleibenden Teil plus Rest berechnen Sie mit der folgenden Formel:

=B1-(B2-1)*GANZZAHL(B1/B2)

Die folgende Abbildung zeigt den Einsatz der Formel in einer Beispieltabelle:

Tipp: Sie können die beiden Formeln mit Textverknüpfungen so kombinieren, dass die Zerlegung in der Form „455 = 7 x 56 + 1 x 63“ in einer Zelle ausgegeben wird. Das erreichen Sie mit der folgenden Formel:

=B1&" = "&B2-1&" x "&GANZZAHL (B1/B2)&" + 1 x "&B1-(B2-1)*GANZZAHL(B1/B2)

Die folgende Abbildung zeigt den Einsatz der Formel in der Beispieltabelle:

Die Beispieltabelle mit den vorgestellten Formeln finden Sie hier in der Mappe TuM_8_11.xls in der Tabelle „Verteilen“.

zurück zum Seitenanfang

Nur Monate in Zellen zulassen

In einer Tabelle soll in einer Zelle sichergestellt werden, dass nur Monate eingegeben werden können. Das erreichen Sie mit der Gültigkeitsprüfung.

Rufen Sie im Menü „Daten“ den Befehl „Gültigkeit“ auf. In der erscheinenden Dialogbox wählen Sie unter „Zulassen“ die Option „Benutzerdefiniert“. In das Eingabefeld „Formel“ geben Sie dann die folgende Formel ein, die die Zelle A1 mit der Beschränkung versieht:

=NICHT(ISTFEHLER(VERGLEICH(A1;TEXT(ZEILE(INDIREKT("1:12"))*30;"MMMM");0)))

Die folgende Abbildung zeigt die Formel in der Dialogbox der Gültigkeitsprüfung:

Nach der Eingabe der Formel wechseln Sie in der Dialogbox in das Register „Eingabemeldung“. Dort tragen Sie einen Text ein, der angezeigt wird, wenn die Zelle aktiv ist. Die folgende Abbildung zeigt dieses Register:

Sobald Sie die Zelle aktivieren, erscheint die Eingabemeldung, die den Anwender in der folgenden Form auf die erwartete Eingabe hinweist:

Nach der Definition der Eingabemeldung wechseln Sie in das Register „Fehlermeldung“:

Dort legen Sie einen Text fest, der erscheint, wenn ein Anwender etwas eingeben möchte, das nicht der Gültigkeitsregel entspricht. Die Meldung sieht folgendermaßen aus:

Nachdem Sie alle Einstellungen vorgenommen haben, bestätigen Sie diese mit „OK“.

Die Beispieltabelle mit der Gültigkeitsprüfung finden Sie hier in der Arbeitsmappe TuM_8_11.xls im Tabellenblatt „Monate“.

zurück zum Seitenanfang

Zahl der Monate zwischen zwei Datumsangaben

Wenn Sie die Zahl der Monate zwischen zwei Datumsangaben berechnen möchten, können Sie leider nicht auf eine Standardfunktion von Excel zurückgreifen.

Wenn das Enddatum in Zelle A2 und das Startdatum in Zelle B2 steht, sieht die Formel für diese Berechnung folgendermaßen aus:

=(JAHR(A2-B2)-1900)*12+MONAT(A2-B2)

Die folgende Abbildung zeigt den Einsatz dieser Formel in der Beispieltabelle:

Beachten Sie unbedingt, dass diese Formel nur dann ein korrektes Ergebnis liefert, wenn im Dialogfenster „Optionen“ (Excel 2010: Register „Datei“ im Menüband, Excel 2007: Office- Schaltfläche, Excel bis einschließlich Version 2003: Menü „Datei“) die Einstellung „1904-Datumswerte“ deaktiviert ist. Das ist allerdings auch die Standardeinstellung.

Die folgende Abbildung zeigt die Dialogbox, in der die Einstellungen vorgenommen werden:

Die Beispieltabelle mit der vorgestellten Darstellung finden Sie hier in der Arbeitsmappe TuM_8_11.xls in der Tabelle „Datum“.

zurück zum Seitenanfang

Installation mit Product Key Card

Aktuell werden viele neue PCs mit einer vorinstallierten Testversion von Office 2010 angeboten. Um diese zu aktivieren und sie damit zu einer vollwertigen Version ohne Einschränkungen zu machen, bietet Microsoft mit der Product Key Card (PKC) eine neue Vertriebsform für Software an.

Das Prinzip ist einfach: Sie kaufen eine Karte mit Produktschlüssel, mit dem Sie die vorinstallierte Software aktivieren oder eine Vollversion herunterladen können.

Beziehen können Sie die PKC über den örtlichen Fachhandel oder bei diversen Online-Händlern. Weitere Informationen zu dieser praktischen Karte und Anleitungen zu ihrem Einsatz finden Sie unter der folgenden Adresse:

http://office.microsoft.com/dede/buy/product-key-karte-FX101828885.aspx

Sie können die PKC auch nutzen, wenn Sie keine Testversion von Office 2010 auf Ihrem PC haben. Weitere Informationen finden Sie unter der folgenden Adresse:

http://office.microsoft.com/dede/buy/verwenden-der-product-keykarte-FX101853163.aspx

zurück zum Seitenanfang

Informationen zur Sicherheit Ihrer Daten

Wenn Daten wie zum Beispiel bei Office 365 auf einem externen Server abgelegt werden, stellt sich schnell die Frage der Datensicherheit. In einem Whitepaper geht Microsoft auf die wichtigsten Fragen ein. Hier ein kurzer Überblick:

Die Daten von Office 365 liegen in riesigen, hochmodernen Rechenzentren, die auf möglichst hohe Sicherheit ausgelegt und sowohl gegen Naturkatastrophen als auch gegen Angriffe von außen geschützt sind. Permanente Überwachung und regelmäßige Updates sorgen für Sicherheit und Aktualität.

Die Datenschutzrichtlinie „Trust Center“ schützt Ihre Daten und bietet Ihnen volle Kontrolle. Die Active-Directory- Technologie teilt Daten auf einem Server sicher unter den Kunden auf, auf Wunsch ist auch eine komplette Datenisolierung möglich.

Die Zugriffskontrolle und der Virenschutz entsprechen höchsten Sicherheitsstandards.

Das komplette englischsprachige Whitepaper finden Sie unter der folgenden Adresse:

http://www.microsoft.com/downloads/e

zurück zum Seitenanfang